Visual Basic Script Stuff

Here's a collection of Visual Basic (vb) Script functions I've collected over the years.

Services
   Check if a particular service is running

File System
   Delete a file
   Find a file if it's in the path
   Find the CDROM Drive
   Find CDROM Drive with Media
   Generate a filename and path for a working file in the %temp% directory
   Find the size of a file
   Find the location of PST files and log them in a SQL database

Network
   Renew a DHCP lease
   Ping a host (using WMI)
   Ping a host using the external ping.exe
   Convert an IP Address Mask to Slashed Notation
   Set a static IP address from a text file

Registry
   Search through the registry using recursion

Misc
   Including common functions and statement in your scripts
   Open the Control Panel Dialogue to the "Connections" option
   Convert a Binary File to a String
   Check if you're running on a Desktop or Laptop

Working With Data Files (INI, XML, SQL) files
   Using SQL to Generate a Self Incrementing Computer Naming System
   Read a Value from an INI File (GetINI)
   Write to an INI file (WriteINI)
   Read a whole section of an INI file
   Write a whole section to an INI file
   Read a value from an XML file

LDAP, AD, Exchange etc
   Get User Information from an Exchange 5.5 GAL
   Check to see if a User Account Exists in AD
   Get Members of an AD Group
   Update the Terminal Services Profile Path to point to a new Server
   Set Exchange 'Send As' and 'Receive As' Permissions

Write to an INI file (WriteINI)

Function WriteIni(strFileName, strSection, strItem, strValue)
Dim bSectionExists, bInSection, bItemExists, bwrote, strPath, strline, strUcaseLine, iReturn, tfSourceINI, tfDestINI, strWorkingFile, aX, sLeftofEquals

strWorkingFile=GenerateTempFileName
DeleteFile(strWorkingFile) ' Delete the temporary file if it exists
bInSection = False
bSectionExists = False
GetINI strFileName, strSection, strItem,"",iReturn
if iReturn = 0 then
    bItemExists = TRUE
else
    bItemExists = FALSE
end if
bwrote = False
Err.Clear
Set tfSourceINI = fso.OpenTextFile(strFileName, 1, True)
Set tfDestINI = fso.OpenTextFile(strWorkingFile, 2, True, TRISTATE_FALSE )
If Err.Number <> 0 Then
    DeleteFile(strWorkingFile)
    Set tfSourceINI = Nothing
    Set tfDestINI = Nothing
    WriteIni = False
    Exit Function
End If
While tfSourceINI.AtEndOfStream = False
    strline = Trim(tfSourceINI.ReadLine)
    strUcaseLine = UCase(strline)
    sLeftofEquals = strUcaseLine
    if Len(strUcaseLine) > 1 then
      aX = Split(strUcaseLine,"=") ' Split up the string at the "="
      sLeftofEquals = Trim(aX(0)) ' Get the left most bit
    end if
    If bwrote = False Then
      If strUcaseLine = UCase("[" & strSection & "]") Then
      bSectionExists = True
      bInSection = True
      ElseIf InStr(strline, "[") = 1 Then
        bInSection = False
      End If
    End If

    If bInSection Then
      If bItemExists = False Then
        tfDestINI.WriteLine strline
        if len(strValue) => 1 then ' Don't write item out if Value is empty
          tfDestINI.WriteLine strItem & "=" & strValue
        end if
        bwrote = True
        bInSection = False
      ElseIf sLeftofEquals = UCase(strItem) Then
        if len(strValue) => 1 then ' Don't write item out if Value is empty
          tfDestINI.WriteLine strItem & "=" & strValue
        end if
        bwrote = True
        bInSection = False
      Else
        tfDestINI.WriteLine strline
      End If
    Else
      tfDestINI.WriteLine strline
    End If
Wend
If bSectionExists = False Then ' strSection doesn't exist
    tfDestINI.WriteLine
    tfDestINI.WriteLine "[" & strSection & "]"
    tfDestINI.WriteLine strItem & "=" & strValue
End If

tfSourceINI.Close
tfDestINI.Close
If Err.Number = 0 Then
    fso.DeleteFile strfilename
    fso.CopyFile strWorkingFile , strFilename
    DeleteFile(strWorkingFile)
    WriteIni = True
Else
    DeleteFile(strWorkingFile)
    WriteIni = False
End If
Set tfSourceINI = Nothing
Set tfDestINI = Nothing
End Function